mirror of
https://github.com/nix-community/home-manager
synced 2024-06-30 18:38:31 +02:00
36a53d9f26
This process was automated by [my fork of `nix-doc-munge`]. All
conversions were automatically checked to produce the same DocBook
result when converted back, modulo minor typographical/formatting
differences on the acceptable-to-desirable spectrum.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
{} +
$ ./format
[my fork of `nix-doc-munge`]: https://github.com/emilazy/nix-doc-munge/tree/home-manager
85 lines
2.2 KiB
Nix
85 lines
2.2 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.programs.zellij;
|
|
yamlFormat = pkgs.formats.yaml { };
|
|
|
|
in {
|
|
meta.maintainers = [ hm.maintainers.mainrs ];
|
|
|
|
options.programs.zellij = {
|
|
enable = mkEnableOption (lib.mdDoc "zellij");
|
|
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.zellij;
|
|
defaultText = literalExpression "pkgs.zellij";
|
|
description = lib.mdDoc ''
|
|
The zellij package to install.
|
|
'';
|
|
};
|
|
|
|
settings = mkOption {
|
|
type = yamlFormat.type;
|
|
default = { };
|
|
example = literalExpression ''
|
|
{
|
|
theme = "custom";
|
|
themes.custom.fg = "#ffffff";
|
|
}
|
|
'';
|
|
description = lib.mdDoc ''
|
|
Configuration written to
|
|
{file}`$XDG_CONFIG_HOME/zellij/config.yaml`.
|
|
|
|
See <https://zellij.dev/documentation> for the full
|
|
list of options.
|
|
'';
|
|
};
|
|
|
|
enableBashIntegration = mkEnableOption (lib.mdDoc "Bash integration") // {
|
|
default = false;
|
|
};
|
|
|
|
enableZshIntegration = mkEnableOption (lib.mdDoc "Zsh integration") // {
|
|
default = false;
|
|
};
|
|
|
|
enableFishIntegration = mkEnableOption (lib.mdDoc "Fish integration") // {
|
|
default = false;
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
home.packages = [ cfg.package ];
|
|
|
|
# Zellij switched from yaml to KDL in version 0.32.0:
|
|
# https://github.com/zellij-org/zellij/releases/tag/v0.32.0
|
|
xdg.configFile."zellij/config.yaml" = mkIf
|
|
(cfg.settings != { } && (versionOlder cfg.package.version "0.32.0")) {
|
|
source = yamlFormat.generate "zellij.yaml" cfg.settings;
|
|
};
|
|
|
|
xdg.configFile."zellij/config.kdl" = mkIf
|
|
(cfg.settings != { } && (versionAtLeast cfg.package.version "0.32.0")) {
|
|
text = lib.hm.generators.toKDL { } cfg.settings;
|
|
};
|
|
|
|
programs.bash.initExtra = mkIf cfg.enableBashIntegration (mkOrder 200 ''
|
|
eval "$(zellij setup --generate-auto-start bash)"
|
|
'');
|
|
|
|
programs.zsh.initExtra = mkIf cfg.enableZshIntegration (mkOrder 200 ''
|
|
eval "$(zellij setup --generate-auto-start zsh)"
|
|
'');
|
|
|
|
programs.fish.interactiveShellInit = mkIf cfg.enableFishIntegration
|
|
(mkOrder 200 ''
|
|
eval (zellij setup --generate-auto-start fish | string collect)
|
|
'');
|
|
};
|
|
}
|