mirror of
https://github.com/nix-community/home-manager
synced 2024-06-30 18:38:31 +02:00
36a53d9f26
This process was automated by [my fork of `nix-doc-munge`]. All
conversions were automatically checked to produce the same DocBook
result when converted back, modulo minor typographical/formatting
differences on the acceptable-to-desirable spectrum.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
{} +
$ ./format
[my fork of `nix-doc-munge`]: https://github.com/emilazy/nix-doc-munge/tree/home-manager
71 lines
1.6 KiB
Nix
71 lines
1.6 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.programs.wofi;
|
|
|
|
toConfig = attrs:
|
|
''
|
|
# Generated by Home Manager.
|
|
'' + generators.toKeyValue { }
|
|
(filterAttrs (name: value: value != null) attrs);
|
|
in {
|
|
meta.maintainers = [ maintainers.christoph-heiss ];
|
|
|
|
options.programs.wofi = {
|
|
enable = mkEnableOption (lib.mdDoc
|
|
"wofi: a launcher/menu program for wlroots based wayland compositors such as sway");
|
|
|
|
package = mkPackageOptionMD pkgs "wofi" { };
|
|
|
|
settings = mkOption {
|
|
default = { };
|
|
type = types.attrs;
|
|
description = lib.mdDoc ''
|
|
Configuration options for wofi. See
|
|
{manpage}`wofi(5)`.
|
|
'';
|
|
example = literalExpression ''
|
|
{
|
|
location = "bottom-right";
|
|
allow_markup = true;
|
|
width = 250;
|
|
}
|
|
'';
|
|
};
|
|
|
|
style = mkOption {
|
|
default = null;
|
|
type = types.nullOr types.str;
|
|
description = lib.mdDoc ''
|
|
CSS style for wofi to use as a stylesheet. See
|
|
{manpage}`wofi(7)`.
|
|
'';
|
|
example = ''
|
|
* {
|
|
font-family: monospace;
|
|
}
|
|
|
|
window {
|
|
background-color: #7c818c;
|
|
}
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
assertions =
|
|
[ (hm.assertions.assertPlatform "programs.wofi" pkgs platforms.linux) ];
|
|
|
|
home.packages = [ cfg.package ];
|
|
|
|
xdg.configFile = mkMerge [
|
|
(mkIf (cfg.settings != { }) {
|
|
"wofi/config".text = toConfig cfg.settings;
|
|
})
|
|
(mkIf (cfg.style != null) { "wofi/style.css".text = cfg.style; })
|
|
];
|
|
};
|
|
}
|