mirror of
https://github.com/nix-community/home-manager
synced 2024-06-30 18:38:31 +02:00
36a53d9f26
This process was automated by [my fork of `nix-doc-munge`]. All
conversions were automatically checked to produce the same DocBook
result when converted back, modulo minor typographical/formatting
differences on the acceptable-to-desirable spectrum.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
{} +
$ ./format
[my fork of `nix-doc-munge`]: https://github.com/emilazy/nix-doc-munge/tree/home-manager
81 lines
2.2 KiB
Nix
81 lines
2.2 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.programs.sioyek;
|
|
|
|
renderConfig = generators.toKeyValue {
|
|
mkKeyValue = key: value: "${key} ${value}";
|
|
listsAsDuplicateKeys = true;
|
|
};
|
|
|
|
in {
|
|
options = {
|
|
programs.sioyek = {
|
|
enable = mkEnableOption (lib.mdDoc
|
|
"Sioyek, a PDF viewer designed for reading research papers and technical books");
|
|
|
|
package = mkOption {
|
|
default = pkgs.sioyek;
|
|
defaultText = literalExpression "pkgs.sioyek";
|
|
type = types.package;
|
|
description = lib.mdDoc "Package providing the sioyek binary";
|
|
};
|
|
|
|
bindings = mkOption {
|
|
description = lib.mdDoc ''
|
|
Input configuration written to
|
|
{file}`$XDG_CONFIG_HOME/sioyek/keys_user.config`.
|
|
See <https://github.com/ahrm/sioyek/blob/main/pdf_viewer/keys.config>.
|
|
|
|
Each attribute could also accept a list of strings to set multiple
|
|
bindings of the same command.
|
|
'';
|
|
type = with types; attrsOf (either str (listOf str));
|
|
default = { };
|
|
example = literalExpression ''
|
|
{
|
|
"move_up" = "k";
|
|
"move_down" = "j";
|
|
"move_left" = "h";
|
|
"move_right" = "l";
|
|
"screen_down" = [ "d" "<C-d>" ];
|
|
"screen_up" = [ "u" "<C-u>" ];
|
|
}
|
|
'';
|
|
};
|
|
|
|
config = mkOption {
|
|
description = lib.mdDoc ''
|
|
Input configuration written to
|
|
{file}`$XDG_CONFIG_HOME/sioyek/prefs_user.config`.
|
|
See <https://github.com/ahrm/sioyek/blob/main/pdf_viewer/prefs.config>.
|
|
'';
|
|
type = types.attrsOf types.str;
|
|
default = { };
|
|
example = literalExpression ''
|
|
{
|
|
"background_color" = "1.0 1.0 1.0";
|
|
"text_highlight_color" = "1.0 0.0 0.0";
|
|
}
|
|
'';
|
|
};
|
|
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable (mkMerge [
|
|
{ home.packages = [ cfg.package ]; }
|
|
(mkIf (cfg.config != { }) {
|
|
xdg.configFile."sioyek/prefs_user.config".text = renderConfig cfg.config;
|
|
})
|
|
(mkIf (cfg.bindings != { }) {
|
|
xdg.configFile."sioyek/keys_user.config".text = renderConfig cfg.bindings;
|
|
})
|
|
]);
|
|
|
|
meta.maintainers = [ hm.maintainers.podocarp ];
|
|
}
|