mirror of
https://github.com/nix-community/home-manager
synced 2024-06-30 18:38:31 +02:00
36a53d9f26
This process was automated by [my fork of `nix-doc-munge`]. All
conversions were automatically checked to produce the same DocBook
result when converted back, modulo minor typographical/formatting
differences on the acceptable-to-desirable spectrum.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
{} +
$ ./format
[my fork of `nix-doc-munge`]: https://github.com/emilazy/nix-doc-munge/tree/home-manager
73 lines
2.1 KiB
Nix
73 lines
2.1 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.programs.senpai;
|
|
cfgFmt = pkgs.formats.yaml { };
|
|
in {
|
|
options.programs.senpai = {
|
|
enable = mkEnableOption (lib.mdDoc "senpai");
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.senpai;
|
|
defaultText = literalExpression "pkgs.senpai";
|
|
description = lib.mdDoc "The `senpai` package to use.";
|
|
};
|
|
config = mkOption {
|
|
type = types.submodule {
|
|
freeformType = cfgFmt.type;
|
|
options = {
|
|
addr = mkOption {
|
|
type = types.str;
|
|
description = lib.mdDoc ''
|
|
The address (host[:port]) of the IRC server. senpai uses TLS
|
|
connections by default unless you specify no-tls option. TLS
|
|
connections default to port 6697, plain-text use port 6667.
|
|
'';
|
|
};
|
|
nick = mkOption {
|
|
type = types.str;
|
|
description = lib.mdDoc ''
|
|
Your nickname, sent with a NICK IRC message. It mustn't contain
|
|
spaces or colons (:).
|
|
'';
|
|
};
|
|
password = mkOption {
|
|
type = types.nullOr types.str;
|
|
default = null;
|
|
description = lib.mdDoc ''
|
|
Your password, used for SASL authentication. Note that it will
|
|
reside world-readable in the Nix store.
|
|
'';
|
|
};
|
|
no-tls = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = lib.mdDoc "Disables TLS encryption.";
|
|
};
|
|
};
|
|
};
|
|
example = literalExpression ''
|
|
{
|
|
addr = "libera.chat:6697";
|
|
nick = "nicholas";
|
|
password = "verysecurepassword";
|
|
}
|
|
'';
|
|
description = lib.mdDoc ''
|
|
Configuration for senpai. For a complete list of options, see
|
|
{manpage}`senpai(5)`.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
home.packages = [ cfg.package ];
|
|
xdg.configFile."senpai/senpai.yaml".source =
|
|
cfgFmt.generate "senpai.yaml" cfg.config;
|
|
};
|
|
|
|
meta.maintainers = [ hm.maintainers.malvo ];
|
|
}
|