mirror of
https://github.com/nix-community/home-manager
synced 2024-09-29 17:57:28 +02:00
36a53d9f26
This process was automated by [my fork of `nix-doc-munge`]. All
conversions were automatically checked to produce the same DocBook
result when converted back, modulo minor typographical/formatting
differences on the acceptable-to-desirable spectrum.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
{} +
$ ./format
[my fork of `nix-doc-munge`]: https://github.com/emilazy/nix-doc-munge/tree/home-manager
85 lines
2 KiB
Nix
85 lines
2 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.programs.readline;
|
|
|
|
mkSetVariableStr = n: v:
|
|
let
|
|
mkValueStr = v:
|
|
if v == true then
|
|
"on"
|
|
else if v == false then
|
|
"off"
|
|
else if isInt v then
|
|
toString v
|
|
else if isString v then
|
|
v
|
|
else
|
|
abort ("values ${toPretty v} is of unsupported type");
|
|
in "set ${n} ${mkValueStr v}";
|
|
|
|
mkBindingStr = k: v:
|
|
let
|
|
isKeynameNotKeyseq = k:
|
|
builtins.elem (builtins.head (lib.splitString "-" (toLower k))) [
|
|
"control"
|
|
"meta"
|
|
];
|
|
in if isKeynameNotKeyseq k then "${k}: ${v}" else ''"${k}": ${v}'';
|
|
|
|
in {
|
|
options.programs.readline = {
|
|
enable = mkEnableOption (lib.mdDoc "readline");
|
|
|
|
bindings = mkOption {
|
|
default = { };
|
|
type = types.attrsOf types.str;
|
|
example = literalExpression ''
|
|
{ "\\C-h" = "backward-kill-word"; }
|
|
'';
|
|
description = lib.mdDoc "Readline bindings.";
|
|
};
|
|
|
|
variables = mkOption {
|
|
type = with types; attrsOf (either str (either int bool));
|
|
default = { };
|
|
example = { expand-tilde = true; };
|
|
description = lib.mdDoc ''
|
|
Readline customization variable assignments.
|
|
'';
|
|
};
|
|
|
|
includeSystemConfig = mkOption {
|
|
type = types.bool;
|
|
default = true;
|
|
description =
|
|
lib.mdDoc "Whether to include the system-wide configuration.";
|
|
};
|
|
|
|
extraConfig = mkOption {
|
|
type = types.lines;
|
|
default = "";
|
|
description = lib.mdDoc ''
|
|
Configuration lines appended unchanged to the end of the
|
|
{file}`~/.inputrc` file.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
home.file.".inputrc".text = let
|
|
configStr = concatStringsSep "\n"
|
|
(optional cfg.includeSystemConfig "$include /etc/inputrc"
|
|
++ mapAttrsToList mkSetVariableStr cfg.variables
|
|
++ mapAttrsToList mkBindingStr cfg.bindings);
|
|
in ''
|
|
# Generated by Home Manager.
|
|
|
|
${configStr}
|
|
${cfg.extraConfig}
|
|
'';
|
|
};
|
|
}
|