mirror of
https://github.com/nix-community/home-manager
synced 2024-06-30 18:38:31 +02:00
36a53d9f26
This process was automated by [my fork of `nix-doc-munge`]. All
conversions were automatically checked to produce the same DocBook
result when converted back, modulo minor typographical/formatting
differences on the acceptable-to-desirable spectrum.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
{} +
$ ./format
[my fork of `nix-doc-munge`]: https://github.com/emilazy/nix-doc-munge/tree/home-manager
52 lines
1.7 KiB
Nix
52 lines
1.7 KiB
Nix
{ config, lib, pkgs, ... }:
|
||
|
||
with lib;
|
||
|
||
let
|
||
|
||
cfg = config.systemd.user.tmpfiles;
|
||
|
||
in {
|
||
meta.maintainers = [ maintainers.dawidsowa ];
|
||
|
||
options.systemd.user.tmpfiles.rules = mkOption {
|
||
type = types.listOf types.str;
|
||
default = [ ];
|
||
example = [ "L /home/user/Documents - - - - /mnt/data/Documents" ];
|
||
description = lib.mdDoc ''
|
||
Rules for creating and cleaning up temporary files
|
||
automatically. See
|
||
{manpage}`tmpfiles.d(5)`
|
||
for the exact format.
|
||
'';
|
||
};
|
||
|
||
config = mkIf (cfg.rules != [ ]) {
|
||
assertions = [
|
||
(hm.assertions.assertPlatform "systemd.user.tmpfiles" pkgs
|
||
platforms.linux)
|
||
];
|
||
|
||
xdg = {
|
||
dataFile."user-tmpfiles.d/home-manager.conf" = {
|
||
text = ''
|
||
# This file is created automatically and should not be modified.
|
||
# Please change the option ‘systemd.user.tmpfiles.rules’ instead.
|
||
${concatStringsSep "\n" cfg.rules}
|
||
'';
|
||
onChange = "${pkgs.systemd}/bin/systemd-tmpfiles --user --create";
|
||
};
|
||
configFile = {
|
||
"systemd/user/basic.target.wants/systemd-tmpfiles-setup.service".source =
|
||
"${pkgs.systemd}/example/systemd/user/systemd-tmpfiles-setup.service";
|
||
"systemd/user/systemd-tmpfiles-setup.service".source =
|
||
"${pkgs.systemd}/example/systemd/user/systemd-tmpfiles-setup.service";
|
||
"systemd/user/timers.target.wants/systemd-tmpfiles-clean.timer".source =
|
||
"${pkgs.systemd}/example/systemd/user/systemd-tmpfiles-clean.timer";
|
||
"systemd/user/systemd-tmpfiles-clean.service".source =
|
||
"${pkgs.systemd}/example/systemd/user/systemd-tmpfiles-clean.service";
|
||
};
|
||
};
|
||
};
|
||
}
|