mirror of
https://github.com/nix-community/home-manager
synced 2024-06-01 20:43:34 +02:00
64ab7d6e8d
* Add flake.lock and clean up flake.nix Add a lockfile to work around https://github.com/NixOS/nix/issues/6541 (and because it's a good idea anyway). Also use flake-utils, and restrict ourselves to the five platforms supported by nixpkgs. Otherwise, the IFD for nmd fails on weird platforms. This fixes `nix flake check`. Remove the redundant `apps` output, see https://github.com/nix-community/home-manager/pull/2442#issuecomment-1133670487 * nixos,nix-darwin: factor out into a common module * nixos,nix-darwin: make `home-managers.users` shallowly visible Make sure the option is included in the NixOS/nix-darwin manual (but the HM submodule options aren't). Also add a static description to the HM submodule type so that we don't need to evaluate the submodules just to build the option manual. This makes nixos-search able to index the home-manager flake. Also clean up some TODOs. * flake: add nmd and nmt This avoids having to use `pkgs.fetchFromGitLab` in an IFD, which causes issues when indexing packages with nixos-search because `pkgs` is instantiated with every platform.
124 lines
3.6 KiB
Nix
124 lines
3.6 KiB
Nix
{ pkgs, nmdSrc ? (import ./.. { }).inputs.nmd
|
|
|
|
# Note, this should be "the standard library" + HM extensions.
|
|
, lib ? import ../modules/lib/stdlib-extended.nix pkgs.lib }:
|
|
|
|
let
|
|
|
|
nmd = import nmdSrc { inherit lib pkgs; };
|
|
|
|
# Make sure the used package is scrubbed to avoid actually
|
|
# instantiating derivations.
|
|
scrubbedPkgsModule = {
|
|
imports = [{
|
|
_module.args = {
|
|
pkgs = lib.mkForce (nmd.scrubDerivations "pkgs" pkgs);
|
|
pkgs_i686 = lib.mkForce { };
|
|
};
|
|
}];
|
|
};
|
|
|
|
buildModulesDocs = args:
|
|
nmd.buildModulesDocs ({
|
|
moduleRootPaths = [ ./.. ];
|
|
mkModuleUrl = path:
|
|
"https://github.com/nix-community/home-manager/blob/master/${path}#blob-path";
|
|
channelName = "home-manager";
|
|
} // args);
|
|
|
|
hmModulesDocs = buildModulesDocs {
|
|
modules = import ../modules/modules.nix {
|
|
inherit lib pkgs;
|
|
check = false;
|
|
} ++ [ scrubbedPkgsModule ];
|
|
docBook.id = "home-manager-options";
|
|
};
|
|
|
|
nixosModuleDocs = buildModulesDocs {
|
|
modules = let
|
|
nixosModule = module: pkgs.path + "/nixos/modules" + module;
|
|
mockedNixos = with lib; {
|
|
options = {
|
|
environment.pathsToLink = mkSinkUndeclaredOptions { };
|
|
systemd.services = mkSinkUndeclaredOptions { };
|
|
users.users = mkSinkUndeclaredOptions { };
|
|
};
|
|
};
|
|
in [
|
|
../nixos/default.nix
|
|
mockedNixos
|
|
(nixosModule "/misc/assertions.nix")
|
|
scrubbedPkgsModule
|
|
];
|
|
docBook = {
|
|
id = "nixos-options";
|
|
optionIdPrefix = "nixos-opt";
|
|
};
|
|
};
|
|
|
|
nixDarwinModuleDocs = buildModulesDocs {
|
|
modules = let
|
|
nixosModule = module: pkgs.path + "/nixos/modules" + module;
|
|
mockedNixDarwin = with lib; {
|
|
options = {
|
|
environment.pathsToLink = mkSinkUndeclaredOptions { };
|
|
system.activationScripts.postActivation.text =
|
|
mkSinkUndeclaredOptions { };
|
|
users.users = mkSinkUndeclaredOptions { };
|
|
};
|
|
};
|
|
in [
|
|
../nix-darwin/default.nix
|
|
mockedNixDarwin
|
|
(nixosModule "/misc/assertions.nix")
|
|
scrubbedPkgsModule
|
|
];
|
|
docBook = {
|
|
id = "nix-darwin-options";
|
|
optionIdPrefix = "nix-darwin-opt";
|
|
};
|
|
};
|
|
|
|
docs = nmd.buildDocBookDocs {
|
|
pathName = "home-manager";
|
|
projectName = "Home Manager";
|
|
modulesDocs = [ hmModulesDocs nixDarwinModuleDocs nixosModuleDocs ];
|
|
documentsDirectory = ./.;
|
|
documentType = "book";
|
|
chunkToc = ''
|
|
<toc>
|
|
<d:tocentry xmlns:d="http://docbook.org/ns/docbook" linkend="book-home-manager-manual"><?dbhtml filename="index.html"?>
|
|
<d:tocentry linkend="ch-options"><?dbhtml filename="options.html"?></d:tocentry>
|
|
<d:tocentry linkend="ch-nixos-options"><?dbhtml filename="nixos-options.html"?></d:tocentry>
|
|
<d:tocentry linkend="ch-nix-darwin-options"><?dbhtml filename="nix-darwin-options.html"?></d:tocentry>
|
|
<d:tocentry linkend="ch-tools"><?dbhtml filename="tools.html"?></d:tocentry>
|
|
<d:tocentry linkend="ch-release-notes"><?dbhtml filename="release-notes.html"?></d:tocentry>
|
|
</d:tocentry>
|
|
</toc>
|
|
'';
|
|
};
|
|
|
|
in {
|
|
inherit nmdSrc;
|
|
|
|
options = {
|
|
json = hmModulesDocs.json.override {
|
|
path = "share/doc/home-manager/options.json";
|
|
};
|
|
};
|
|
|
|
manPages = docs.manPages;
|
|
|
|
manual = { inherit (docs) html htmlOpenTool; };
|
|
|
|
# Unstable, mainly for CI.
|
|
jsonModuleMaintainers = pkgs.writeText "hm-module-maintainers.json" (let
|
|
result = lib.evalModules {
|
|
modules = import ../modules/modules.nix {
|
|
inherit lib pkgs;
|
|
check = false;
|
|
} ++ [ scrubbedPkgsModule ];
|
|
};
|
|
in builtins.toJSON result.config.meta.maintainers);
|
|
}
|