mirror of
https://github.com/nix-community/home-manager
synced 2024-11-05 10:49:44 +01:00
9f9e277b60
These (and the `*MD` functions apart from `literalMD`) are now no-ops
in nixpkgs and serve no purpose other than to add additional noise and
potentially mislead people into thinking unmarked DocBook documentation
will still be accepted.
Note that if backporting changes including documentation to 23.05,
the `mdDoc` calls will need to be re-added.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
--strip {} +
$ ./format
76 lines
1.9 KiB
Nix
76 lines
1.9 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.programs.yt-dlp;
|
|
|
|
renderSettings = mapAttrsToList (name: value:
|
|
if isBool value then
|
|
if value then "--${name}" else "--no-${name}"
|
|
else
|
|
"--${name} ${toString value}");
|
|
|
|
in {
|
|
meta.maintainers = [ ];
|
|
|
|
options.programs.yt-dlp = {
|
|
enable = mkEnableOption "yt-dlp";
|
|
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.yt-dlp;
|
|
defaultText = literalExpression "pkgs.yt-dlp";
|
|
description = "Package providing the {command}`yt-dlp` tool.";
|
|
};
|
|
|
|
settings = mkOption {
|
|
type = with types; attrsOf (oneOf [ bool int str ]);
|
|
default = { };
|
|
example = literalExpression ''
|
|
{
|
|
embed-thumbnail = true;
|
|
embed-subs = true;
|
|
sub-langs = "all";
|
|
downloader = "aria2c";
|
|
downloader-args = "aria2c:'-c -x8 -s8 -k1M'";
|
|
}
|
|
'';
|
|
description = ''
|
|
Configuration written to
|
|
{file}`$XDG_CONFIG_HOME/yt-dlp/config`.
|
|
|
|
Options must be specified in their "long form", for
|
|
example, `update = true;` instead of `U = true;`.
|
|
Short options can be specified in the `extraConfig` option.
|
|
See <https://github.com/yt-dlp/yt-dlp#configuration>
|
|
for explanation about possible values.
|
|
'';
|
|
};
|
|
|
|
extraConfig = mkOption {
|
|
type = types.lines;
|
|
default = "";
|
|
example = ''
|
|
--update
|
|
-F
|
|
'';
|
|
description = ''
|
|
Extra configuration to add to
|
|
{file}`$XDG_CONFIG_HOME/yt-dlp/config`.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
home.packages = [ cfg.package ];
|
|
|
|
xdg.configFile."yt-dlp/config" =
|
|
mkIf (cfg.settings != { } || cfg.extraConfig != "") {
|
|
text = concatStringsSep "\n"
|
|
(remove "" (renderSettings cfg.settings ++ [ cfg.extraConfig ]))
|
|
+ "\n";
|
|
};
|
|
};
|
|
}
|