mirror of
https://github.com/nix-community/home-manager
synced 2024-06-02 21:13:33 +02:00
9f9e277b60
These (and the `*MD` functions apart from `literalMD`) are now no-ops
in nixpkgs and serve no purpose other than to add additional noise and
potentially mislead people into thinking unmarked DocBook documentation
will still be accepted.
Note that if backporting changes including documentation to 23.05,
the `mdDoc` calls will need to be re-added.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
--strip {} +
$ ./format
94 lines
2.3 KiB
Nix
94 lines
2.3 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.services.xsettingsd;
|
|
|
|
renderSettings = settings:
|
|
concatStrings (mapAttrsToList renderSetting settings);
|
|
|
|
renderSetting = key: value: ''
|
|
${key} ${renderValue value}
|
|
'';
|
|
|
|
renderValue = value:
|
|
{
|
|
int = toString value;
|
|
bool = if value then "1" else "0";
|
|
string = ''"${value}"'';
|
|
}.${builtins.typeOf value};
|
|
|
|
in {
|
|
meta.maintainers = [ maintainers.imalison ];
|
|
|
|
options = {
|
|
services.xsettingsd = {
|
|
enable = mkEnableOption "xsettingsd";
|
|
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.xsettingsd;
|
|
defaultText = literalExpression "pkgs.xsettingsd";
|
|
description = ''
|
|
Package containing the {command}`xsettingsd` program.
|
|
'';
|
|
};
|
|
|
|
settings = mkOption {
|
|
type = with types; attrsOf (oneOf [ bool int str ]);
|
|
default = { };
|
|
example = literalExpression ''
|
|
{
|
|
"Net/ThemeName" = "Numix";
|
|
"Xft/Antialias" = true;
|
|
"Xft/Hinting" = true;
|
|
"Xft/RGBA" = "rgb";
|
|
}
|
|
'';
|
|
description = ''
|
|
Xsettingsd options for configuration file. See
|
|
<https://github.com/derat/xsettingsd/wiki/Settings>
|
|
for documentation on these values.
|
|
'';
|
|
};
|
|
|
|
configFile = mkOption {
|
|
type = types.nullOr types.package;
|
|
internal = true;
|
|
readOnly = true;
|
|
default = if cfg.settings == { } then
|
|
null
|
|
else
|
|
pkgs.writeText "xsettingsd.conf" (renderSettings cfg.settings);
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
assertions = [
|
|
(lib.hm.assertions.assertPlatform "services.xsettingsd" pkgs
|
|
lib.platforms.linux)
|
|
];
|
|
|
|
systemd.user.services.xsettingsd = {
|
|
Unit = {
|
|
Description = "xsettingsd";
|
|
After = [ "graphical-session-pre.target" ];
|
|
PartOf = [ "graphical-session.target" ];
|
|
};
|
|
|
|
Install.WantedBy = [ "graphical-session.target" ];
|
|
|
|
Service = {
|
|
Environment = "PATH=${config.home.profileDirectory}/bin";
|
|
ExecStart = "${cfg.package}/bin/xsettingsd"
|
|
+ optionalString (cfg.configFile != null)
|
|
" -c ${escapeShellArg cfg.configFile}";
|
|
Restart = "on-abort";
|
|
};
|
|
};
|
|
};
|
|
}
|