From f44d4a1d8611c8b2f1fce97dc7810722aa10c8cb Mon Sep 17 00:00:00 2001
From: adisbladis <adisbladis@gmail.com>
Date: Wed, 26 Sep 2018 11:55:51 +0800
Subject: [PATCH] obs-studio: add module

---
 modules/misc/news.nix           |  8 ++++++
 modules/modules.nix             |  1 +
 modules/programs/obs-studio.nix | 48 +++++++++++++++++++++++++++++++++
 3 files changed, 57 insertions(+)
 create mode 100644 modules/programs/obs-studio.nix

diff --git a/modules/misc/news.nix b/modules/misc/news.nix
index c79962c49..c2aefafda 100644
--- a/modules/misc/news.nix
+++ b/modules/misc/news.nix
@@ -807,6 +807,14 @@ in
           A new module is available: 'programs.go'.
         '';
       }
+
+      {
+        time = "2018-09-27T17:48:08+00:00";
+        message = ''
+          A new module is available: 'programs.obs-studio'.
+        '';
+      }
+
     ];
   };
 }
diff --git a/modules/modules.nix b/modules/modules.nix
index c5e96b33d..8da265ce1 100644
--- a/modules/modules.nix
+++ b/modules/modules.nix
@@ -51,6 +51,7 @@ let
     ./programs/newsboat.nix
     ./programs/noti.nix
     ./programs/notmuch.nix
+    ./programs/obs-studio.nix
     ./programs/offlineimap.nix
     ./programs/pidgin.nix
     ./programs/rofi.nix
diff --git a/modules/programs/obs-studio.nix b/modules/programs/obs-studio.nix
new file mode 100644
index 000000000..9f9310c95
--- /dev/null
+++ b/modules/programs/obs-studio.nix
@@ -0,0 +1,48 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+
+  cfg = config.programs.obs-studio;
+  package = pkgs.obs-studio;
+
+  mkPluginEnv = packages:
+    let
+      pluginDirs = map (pkg: "${pkg}/share/obs/obs-plugins") packages;
+      plugins = concatMapStringsSep " " (p: "${p}/*") pluginDirs;
+    in
+      pkgs.runCommand "obs-studio-plugins" {} ''
+        mkdir $out
+        [[ '${plugins}' ]] || exit 0
+        for plugin in ${plugins}; do
+          ln -s "$plugin" $out/
+        done
+      '';
+
+in
+
+{
+  meta.maintainers = [ maintainers.adisbladis ];
+
+  options = {
+    programs.obs-studio = {
+      enable = mkEnableOption "obs-studio";
+
+      plugins = mkOption {
+        default = [];
+        example = literalExample "[ pkgs.obs-linuxbrowser ]";
+        description = "Optional OBS plugins.";
+        type = types.listOf types.package;
+      };
+    };
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = [ package ];
+
+    xdg.configFile."obs-studio/plugins" = mkIf (cfg.plugins != []) {
+      source = mkPluginEnv cfg.plugins;
+    };
+  };
+}