From d1980931de8252b6ac1104b7191fd68bbbe3a291 Mon Sep 17 00:00:00 2001
From: Jan Schmitz <44864658+danjujan@users.noreply.github.com>
Date: Sun, 28 Apr 2024 19:35:01 +0200
Subject: [PATCH] psd: add module

PR #5349
---
 modules/lib/maintainers.nix |  6 +++
 modules/misc/news.nix       | 12 +++++
 modules/modules.nix         |  1 +
 modules/services/psd.nix    | 88 +++++++++++++++++++++++++++++++++++++
 4 files changed, 107 insertions(+)
 create mode 100644 modules/services/psd.nix

diff --git a/modules/lib/maintainers.nix b/modules/lib/maintainers.nix
index a2c568633..f3dd83fe5 100644
--- a/modules/lib/maintainers.nix
+++ b/modules/lib/maintainers.nix
@@ -55,6 +55,12 @@
     github = "cvoges12";
     githubId = 38054771;
   };
+  danjujan = {
+    name = "Jan Schmitz";
+    email = "44864658+danjujan@users.noreply.github.com";
+    github = "danjujan";
+    githubId = 44864658;
+  };
   d-dervishi = {
     email = "david.dervishi@epfl.ch";
     github = "d-dervishi";
diff --git a/modules/misc/news.nix b/modules/misc/news.nix
index 88e43a4c0..f8617f54a 100644
--- a/modules/misc/news.nix
+++ b/modules/misc/news.nix
@@ -1537,6 +1537,18 @@ in {
           for more.
         '';
       }
+
+      {
+        time = "2024-04-28T20:27:08+00:00";
+        condition = hostPlatform.isLinux;
+        message = ''
+          A new module is available: 'services.psd'.
+
+          Profile-sync-daemon (psd) is a tiny pseudo-daemon designed to manage
+          your browser's profile in tmpfs and to periodically sync it back to
+          your physical disc (HDD/SSD).
+        '';
+      }
     ];
   };
 }
diff --git a/modules/modules.nix b/modules/modules.nix
index 06d1c3315..b1e8b9b42 100644
--- a/modules/modules.nix
+++ b/modules/modules.nix
@@ -337,6 +337,7 @@ let
     ./services/plex-mpv-shim.nix
     ./services/polybar.nix
     ./services/poweralertd.nix
+    ./services/psd.nix
     ./services/pueue.nix
     ./services/pulseeffects.nix
     ./services/random-background.nix
diff --git a/modules/services/psd.nix b/modules/services/psd.nix
new file mode 100644
index 000000000..477176aa3
--- /dev/null
+++ b/modules/services/psd.nix
@@ -0,0 +1,88 @@
+{ config, lib, pkgs, ... }:
+
+let
+
+  cfg = config.services.psd;
+
+in {
+  meta.maintainers = [ lib.hm.maintainers.danjujan ];
+
+  options.services.psd = {
+    enable = lib.mkEnableOption "Profile-sync-daemon service";
+
+    resyncTimer = lib.mkOption {
+      type = lib.types.str;
+      default = "1h";
+      example = "1h 30min";
+      description = ''
+        The amount of time to wait before syncing browser profiles back to the
+        disk.
+
+        Takes a systemd time span, see {manpage}`systemd.time(7)`. The time unit
+        defaults to seconds if omitted.
+      '';
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    assertions = [
+      (lib.hm.assertions.assertPlatform "services.psd" pkgs lib.platforms.linux)
+    ];
+
+    home.packages = [ pkgs.profile-sync-daemon ];
+
+    systemd.user = {
+      services = let
+        exe = "${pkgs.profile-sync-daemon}/bin/profile-sync-daemon";
+        envPath = lib.makeBinPath (with pkgs; [
+          rsync
+          kmod
+          gawk
+          nettools
+          util-linux
+          profile-sync-daemon
+        ]);
+      in {
+        psd = {
+          Unit = {
+            Description = "Profile-sync-daemon";
+            Wants = [ "psd-resync.service" ];
+            RequiresMountsFor = [ "/home/" ];
+            After = "winbindd.service";
+          };
+          Service = {
+            Type = "oneshot";
+            RemainAfterExit = "yes";
+            ExecStart = "${exe} startup";
+            ExecStop = "${exe} unsync";
+            Environment = [ "LAUNCHED_BY_SYSTEMD=1" "PATH=$PATH:${envPath}" ];
+          };
+          Install = { WantedBy = [ "default.target" ]; };
+        };
+
+        psd-resync = {
+          Unit = {
+            Description = "Timed profile resync";
+            After = [ "psd.service" ];
+            Wants = [ "psd-resync.timer" ];
+            PartOf = [ "psd.service" ];
+          };
+          Service = {
+            Type = "oneshot";
+            ExecStart = "${exe} resync";
+            Environment = [ "PATH=$PATH:${envPath}" ];
+          };
+          Install = { WantedBy = [ "default.target" ]; };
+        };
+      };
+
+      timers.psd-resync = {
+        Unit = {
+          Description = "Timer for Profile-sync-daemon";
+          PartOf = [ "psd-resync.service" "psd.service" ];
+        };
+        Timer = { OnUnitActiveSec = cfg.resyncTimer; };
+      };
+    };
+  };
+}