easyeffects: add module (#2182)

* pulseeffects: change default example

pulseeffects-pw is now an alias to easyeffects, and the `pulseeffects` binary
that this module references is no longer in that package.

* easyeffects: add module

The easyeffects service is the PipeWire equivalent of the pulseeffects
service.

.github/CODEOWNERS

@@ -227,6 +227,8 @@
 
 /modules/services/dunst.nix                           @rycee
 
+/modules/services/easyeffects.nix                     @fufexan
+
 /modules/services/emacs.nix                           @tadfisher
 
 /modules/services/etesync-dav.nix                     @Valodim

modules/misc/news.nix

@@ -2164,6 +2164,14 @@ in
           A new module is available: 'programs.java'.
         '';
       }
+
+      {
+        time = "2021-08-11T13:55:51+00:00";
+        condition = hostPlatform.isLinux;
+        message = ''
+          A new module is available: 'services.easyeffects'.
+        '';
+      }
     ];
   };
 }

modules/modules.nix

@@ -157,6 +157,7 @@ let
     ./services/dropbox.nix
     ./services/dunst.nix
     ./services/dwm-status.nix
+    ./services/easyeffects.nix
     ./services/emacs.nix
     ./services/etesync-dav.nix
     ./services/flameshot.nix

modules/services/easyeffects.nix

@@ -0,0 +1,63 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+
+  cfg = config.services.easyeffects;
+
+  presetOpts = optionalString (cfg.preset != "") "--load-preset ${cfg.preset}";
+
+in {
+  meta.maintainers = [ maintainers.fufexan ];
+
+  options.services.easyeffects = {
+    enable = mkEnableOption ''
+      Easyeffects daemon.
+      Note, it is necessary to add
+      <programlisting language="nix">
+      services.dbus.packages = with pkgs; [ gnome.dconf ];
+      </programlisting>
+      to your system configuration for the daemon to work correctly
+    '';
+
+    preset = mkOption {
+      type = types.str;
+      default = "";
+      description = ''
+        Which preset to use when starting easyeffects.
+        Will likely need to launch easyeffects to initially create preset.
+      '';
+    };
+  };
+
+  config = mkIf cfg.enable {
+    assertions = [
+      (hm.assertions.assertPlatform "services.easyeffects" pkgs platforms.linux)
+    ];
+
+    # running easyeffects will just attach itself to gapplication service
+    # at-spi2-core is to minimize journalctl noise of:
+    # "AT-SPI: Error retrieving accessibility bus address: org.freedesktop.DBus.Error.ServiceUnknown: The name org.a11y.Bus was not provided by any .service files"
+    home.packages = with pkgs; [ easyeffects at-spi2-core ];
+
+    systemd.user.services.easyeffects = {
+      Unit = {
+        Description = "Easyeffects daemon";
+        Requires = [ "dbus.service" ];
+        After = [ "graphical-session-pre.target" ];
+        PartOf = [ "graphical-session.target" "pipewire.service" ];
+      };
+
+      Install.WantedBy = [ "graphical-session.target" ];
+
+      Service = {
+        ExecStart =
+          "${pkgs.easyeffects}/bin/easyeffects --gapplication-service ${presetOpts}";
+        ExecStop = "${pkgs.easyeffects}/bin/easyeffects --quit";
+        Restart = "on-failure";
+        RestartSec = 5;
+      };
+    };
+  };
+}

modules/services/pulseeffects.nix

@@ -16,10 +16,9 @@ in {
 
     package = mkOption {
       type = types.package;
-      default = pkgs.pulseeffects;
-      defaultText = literalExample "pkgs.pulseeffects";
+      default = pkgs.pulseeffects-legacy;
+      defaultText = literalExample "pkgs.pulseeffects-legacy";
       description = "Pulseeffects package to use.";
-      example = literalExample "pkgs.pulseeffects-pw";
     };
 
     preset = mkOption {