diff --git a/modules/lib/maintainers.nix b/modules/lib/maintainers.nix
index 6645e7c2a..1f976d8ae 100644
--- a/modules/lib/maintainers.nix
+++ b/modules/lib/maintainers.nix
@@ -335,6 +335,12 @@
     github = "sebtm";
     githubId = 17243347;
   };
+  rasmus-kirk = {
+    name = "Rasmus Kirk";
+    email = "mail@rasmuskirk.com";
+    github = "rasmus-kirk";
+    githubId = 57323869;
+  };
   rosuavio = {
     name = "Rosario Pulella";
     email = "RosarioPulella@gmail.com";
diff --git a/modules/modules.nix b/modules/modules.nix
index 736922d5d..e2d3fb0cf 100644
--- a/modules/modules.nix
+++ b/modules/modules.nix
@@ -105,6 +105,7 @@ let
     ./programs/java.nix
     ./programs/jq.nix
     ./programs/jujutsu.nix
+    ./programs/joshuto.nix
     ./programs/just.nix
     ./programs/k9s.nix
     ./programs/kakoune.nix
diff --git a/modules/programs/joshuto.nix b/modules/programs/joshuto.nix
new file mode 100644
index 000000000..63c325236
--- /dev/null
+++ b/modules/programs/joshuto.nix
@@ -0,0 +1,88 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+  cfg = config.programs.joshuto;
+  tomlFormat = pkgs.formats.toml { };
+in {
+  meta.maintainers = [ hm.maintainers.rasmus-kirk ];
+
+  options.programs.joshuto = {
+    enable = mkEnableOption "joshuto file manager";
+
+    package = mkOption {
+      type = types.package;
+      default = pkgs.joshuto;
+      defaultText = literalExpression "pkgs.joshuto";
+      description = "The package to use for joshuto.";
+    };
+
+    settings = mkOption {
+      type = tomlFormat.type;
+      default = { };
+      description = ''
+        Configuration written to
+        <filename>$XDG_CONFIG_HOME/joshuto/joshuto.toml</filename>.
+        </para><para>
+        See <link xlink:href="https://github.com/kamiyaa/joshuto/blob/main/docs/configuration/joshuto.toml.md" />
+        for the full list of options.
+      '';
+    };
+
+    keymap = mkOption {
+      type = tomlFormat.type;
+      default = { };
+      description = ''
+        Configuration written to
+        <filename>$XDG_CONFIG_HOME/joshuto/keymap.toml</filename>.
+        </para><para>
+        See <link xlink:href="https://github.com/kamiyaa/joshuto/blob/main/docs/configuration/keymap.toml.md" />
+        for the full list of options. Note that this option will overwrite any existing keybinds.
+      '';
+    };
+
+    mimetype = mkOption {
+      type = tomlFormat.type;
+      default = { };
+      description = ''
+        Configuration written to
+        <filename>$XDG_CONFIG_HOME/joshuto/mimetype.toml</filename>.
+        </para><para>
+        See <link xlink:href="https://github.com/kamiyaa/joshuto/blob/main/docs/configuration/mimetype.toml.md" />
+        for the full list of options
+      '';
+    };
+
+    theme = mkOption {
+      type = tomlFormat.type;
+      default = { };
+      description = ''
+        Configuration written to
+        <filename>$XDG_CONFIG_HOME/joshuto/theme.toml</filename>.
+        </para><para>
+        See <link xlink:href="https://github.com/kamiyaa/joshuto/blob/main/docs/configuration/theme.toml.md" />
+        for the full list of options
+      '';
+    };
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = [ cfg.package ];
+
+    xdg.configFile = {
+      "joshuto/joshuto.toml" = mkIf (cfg.settings != { }) {
+        source = tomlFormat.generate "joshuto-settings" cfg.settings;
+      };
+      "joshuto/keymap.toml" = mkIf (cfg.keymap != { }) {
+        source = tomlFormat.generate "joshuto-keymap" cfg.keymap;
+      };
+      "joshuto/mimetype.toml" = mkIf (cfg.mimetype != { }) {
+        source = tomlFormat.generate "joshuto-mimetype" cfg.mimetype;
+      };
+      "joshuto/theme.toml" = mkIf (cfg.theme != { }) {
+        source = tomlFormat.generate "joshuto-theme" cfg.theme;
+      };
+    };
+  };
+}