From 3b67ae3f665379c06999641f99d94dba75b53876 Mon Sep 17 00:00:00 2001
From: Janik <80165193+Janik-Haag@users.noreply.github.com>
Date: Sun, 15 Oct 2023 14:03:18 +0200
Subject: [PATCH] services.cliphist: add module (#4445)

---
 modules/modules.nix                           |  1 +
 modules/services/cliphist.nix                 | 50 +++++++++++++++++++
 tests/default.nix                             |  1 +
 .../cliphist/cliphist-sway-session-target.nix | 17 +++++++
 tests/modules/services/cliphist/default.nix   |  1 +
 5 files changed, 70 insertions(+)
 create mode 100644 modules/services/cliphist.nix
 create mode 100644 tests/modules/services/cliphist/cliphist-sway-session-target.nix
 create mode 100644 tests/modules/services/cliphist/default.nix

diff --git a/modules/modules.nix b/modules/modules.nix
index 35bf06ff7..f4a622c1e 100644
--- a/modules/modules.nix
+++ b/modules/modules.nix
@@ -249,6 +249,7 @@ let
     ./services/cachix-agent.nix
     ./services/caffeine.nix
     ./services/cbatticon.nix
+    ./services/cliphist.nix
     ./services/clipman.nix
     ./services/clipmenu.nix
     ./services/comodoro.nix
diff --git a/modules/services/cliphist.nix b/modules/services/cliphist.nix
new file mode 100644
index 000000000..6ba733fa5
--- /dev/null
+++ b/modules/services/cliphist.nix
@@ -0,0 +1,50 @@
+{ config, lib, pkgs, ... }:
+let cfg = config.services.cliphist;
+in {
+  meta.maintainers = [ lib.maintainers.janik ];
+
+  options.services.cliphist = {
+    enable =
+      lib.mkEnableOption "cliphist, a clipboard history “manager” for wayland";
+
+    package = lib.mkPackageOption pkgs "cliphist" { };
+
+    systemdTarget = lib.mkOption {
+      type = lib.types.str;
+      default = "graphical-session.target";
+      example = "sway-session.target";
+      description = ''
+        The systemd target that will automatically start the cliphist service.
+
+        When setting this value to `"sway-session.target"`,
+        make sure to also enable {option}`wayland.windowManager.sway.systemd.enable`,
+        otherwise the service may never be started.
+      '';
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    assertions = [
+      (lib.hm.assertions.assertPlatform "services.cliphist" pkgs
+        lib.platforms.linux)
+    ];
+
+    home.packages = [ cfg.package ];
+
+    systemd.user.services.cliphist = {
+      Unit = {
+        Description = "Clipboard management daemon";
+        PartOf = [ "graphical-session.target" ];
+      };
+
+      Service = {
+        Type = "simple";
+        ExecStart =
+          "${pkgs.wl-clipboard}/bin/wl-paste --watch ${cfg.package}/bin/cliphist store";
+        Restart = "on-failure";
+      };
+
+      Install = { WantedBy = [ cfg.systemdTarget ]; };
+    };
+  };
+}
diff --git a/tests/default.nix b/tests/default.nix
index 182c7e27e..b02d4c79e 100644
--- a/tests/default.nix
+++ b/tests/default.nix
@@ -205,6 +205,7 @@ import nmt {
     ./modules/services/barrier
     ./modules/services/borgmatic
     ./modules/services/cachix-agent
+    ./modules/services/cliphist
     ./modules/services/clipman
     ./modules/services/comodoro
     ./modules/services/devilspie2
diff --git a/tests/modules/services/cliphist/cliphist-sway-session-target.nix b/tests/modules/services/cliphist/cliphist-sway-session-target.nix
new file mode 100644
index 000000000..25da0f137
--- /dev/null
+++ b/tests/modules/services/cliphist/cliphist-sway-session-target.nix
@@ -0,0 +1,17 @@
+{ ... }:
+
+{
+  services.cliphist = {
+    enable = true;
+    systemdTarget = "sway-session.target";
+  };
+
+  test.stubs = {
+    cliphist = { };
+    wl-clipboard = { };
+  };
+
+  nmt.script = ''
+    assertFileExists home-files/.config/systemd/user/cliphist.service
+  '';
+}
diff --git a/tests/modules/services/cliphist/default.nix b/tests/modules/services/cliphist/default.nix
new file mode 100644
index 000000000..011013322
--- /dev/null
+++ b/tests/modules/services/cliphist/default.nix
@@ -0,0 +1 @@
+{ cliphist-sway-session-target = ./cliphist-sway-session-target.nix; }