alacritty: make compatible with alacritty 0.13

The config file is in TOML from 0.13 onwards.

modules/programs/alacritty.nix

@@ -4,7 +4,9 @@ with lib;
 
 let
   cfg = config.programs.alacritty;
-  yamlFormat = pkgs.formats.yaml { };
+  useToml = lib.versionAtLeast cfg.package.version "0.13";
+  tomlFormat = pkgs.formats.toml { };
+  configFileName = "alacritty.${if useToml then "toml" else "yml"}";
 in {
   options = {
     programs.alacritty = {
@@ -18,7 +20,7 @@ in {
       };
 
       settings = mkOption {
-        type = yamlFormat.type;
+        type = tomlFormat.type;
         default = { };
         example = literalExpression ''
           {
@@ -26,7 +28,7 @@ in {
               lines = 3;
               columns = 200;
             };
-            key_bindings = [
+            keyboard.bindings = [
               {
                 key = "K";
                 mods = "Control";
@@ -37,27 +39,37 @@ in {
         '';
         description = ''
           Configuration written to
-          {file}`$XDG_CONFIG_HOME/alacritty/alacritty.yml`. See
+          {file}`$XDG_CONFIG_HOME/alacritty/alacritty.yml` or
-          <https://github.com/alacritty/alacritty/blob/master/alacritty.yml>
+          {file}`$XDG_CONFIG_HOME/alacritty/alacritty.toml`
-          for the default configuration.
+          (the latter being used for alacritty 0.13 and later).
+          See <https://github.com/alacritty/alacritty/tree/master#configuration>
+          for more info.
         '';
       };
     };
   };
 
-  config = mkMerge [
+  config = mkIf cfg.enable {
-    (mkIf cfg.enable {
     home.packages = [ cfg.package ];
 
-      xdg.configFile."alacritty/alacritty.yml" = mkIf (cfg.settings != { }) {
+    xdg.configFile."alacritty/${configFileName}" =
-        # TODO: Replace by the generate function but need to figure out how to
+      lib.mkIf (cfg.settings != { }) (lib.mkMerge [
-        # handle the escaping first.
+        (lib.mkIf useToml {
-        #
+          source =
-        # source = yamlFormat.generate "alacritty.yml" cfg.settings;
+            (tomlFormat.generate configFileName cfg.settings).overrideAttrs
-
+            (finalAttrs: prevAttrs: {
+              buildCommand = lib.concatStringsSep "\n" [
+                prevAttrs.buildCommand
+                # TODO: why is this needed? Is there a better way to retain escape sequences?
+                "substituteInPlace $out --replace '\\\\' '\\'"
+              ];
+            });
+        })
+        # TODO remove this once we don't need to support Alacritty < 0.12 anymore
+        (lib.mkIf (!useToml) {
           text =
             replaceStrings [ "\\\\" ] [ "\\" ] (builtins.toJSON cfg.settings);
-      };
         })
-  ];
+      ]);
+  };
 }

tests/modules/programs/alacritty/default.nix

@@ -2,4 +2,5 @@
   alacritty-example-settings = ./example-settings.nix;
   alacritty-empty-settings = ./empty-settings.nix;
   alacritty-merging-settings = ./settings-merging.nix;
+  alacritty-toml-config = ./toml_config.nix;
 }

tests/modules/programs/alacritty/example-settings-expected.toml

@@ -0,0 +1,8 @@
+[[keyboard.bindings]]
+chars = "\x0c"
+key = "K"
+mods = "Control"
+
+[window.dimensions]
+columns = 200
+lines = 3

tests/modules/programs/alacritty/example-settings-expected.yml

@@ -1 +0,0 @@
-{"key_bindings":[{"chars":"\x0c","key":"K","mods":"Control"}],"window":{"dimensions":{"columns":200,"lines":3}}}

tests/modules/programs/alacritty/example-settings.nix

@@ -6,7 +6,7 @@ with lib;
   config = {
     programs.alacritty = {
       enable = true;
-      package = config.lib.test.mkStubPackage { };
+      package = config.lib.test.mkStubPackage { version = "0.13.0"; };
 
       settings = {
         window.dimensions = {
@@ -14,7 +14,7 @@ with lib;
           columns = 200;
         };
 
-        key_bindings = [{
+        keyboard.bindings = [{
           key = "K";
           mods = "Control";
           chars = "\\x0c";
@@ -24,8 +24,8 @@ with lib;
 
     nmt.script = ''
       assertFileContent \
-        home-files/.config/alacritty/alacritty.yml \
+        home-files/.config/alacritty/alacritty.toml \
-        ${./example-settings-expected.yml}
+        ${./example-settings-expected.toml}
     '';
   };
 }

tests/modules/programs/alacritty/settings-merging.nix

@@ -6,7 +6,7 @@ with lib;
   config = {
     programs.alacritty = {
       enable = true;
-      package = config.lib.test.mkStubPackage { };
+      package = config.lib.test.mkStubPackage { version = "0.12.3"; };
 
       settings = {
         window.dimensions = {

tests/modules/programs/alacritty/settings-toml-expected.toml

@@ -0,0 +1,15 @@
+[font]
+[font.bold]
+family = "SFMono"
+
+[font.normal]
+family = "SFMono"
+
+[[keyboard.bindings]]
+chars = "\x0c"
+key = "K"
+mods = "Control"
+
+[window.dimensions]
+columns = 200
+lines = 3

tests/modules/programs/alacritty/toml_config.nix

@@ -0,0 +1,34 @@
+{ config, ... }:
+
+{
+  config = {
+    programs.alacritty = {
+      enable = true;
+      package = config.lib.test.mkStubPackage { version = "0.13.0"; };
+
+      settings = {
+        window.dimensions = {
+          lines = 3;
+          columns = 200;
+        };
+
+        keyboard.bindings = [{
+          key = "K";
+          mods = "Control";
+          chars = "\\x0c";
+        }];
+
+        font = {
+          normal.family = "SFMono";
+          bold.family = "SFMono";
+        };
+      };
+    };
+
+    nmt.script = ''
+      assertFileContent \
+        home-files/.config/alacritty/alacritty.toml \
+        ${./settings-toml-expected.toml}
+    '';
+  };
+}