mirror of
https://github.com/justinwoo/easy-dhall-nix.git
synced 2024-06-30 16:38:35 +02:00
5e05faf619
fetchurl does not unpack, but we need it to support MacOS prefetch, because the `--unpack` option to `nix-prefetch-url` does not handle zips with multiple directories in them, and some upstream tarballs switched to that.
54 lines
1.4 KiB
Nix
54 lines
1.4 KiB
Nix
{ pkgs, release }:
|
||
|
||
{ simpleName, binNames, attrName }:
|
||
|
||
let
|
||
release = import ./release.nix;
|
||
in
|
||
|
||
pkgs.stdenv.mkDerivation rec {
|
||
name = simpleName;
|
||
|
||
src = if pkgs.stdenv.isDarwin
|
||
then pkgs.fetchurl {
|
||
url = release.${"${attrName}-darwin"}.url;
|
||
sha256 = release.${"${attrName}-darwin"}.hash;
|
||
}
|
||
else pkgs.fetchurl {
|
||
url = release.${"${attrName}-linux"}.url;
|
||
sha256 = release.${"${attrName}-linux"}.hash;
|
||
};
|
||
|
||
nativeBuildInputs = [ pkgs.installShellFiles ];
|
||
|
||
passthru.binNames = binNames;
|
||
|
||
installPhase = ''
|
||
mkdir -p $out/bin
|
||
|
||
${pkgs.lib.concatMapStringsSep "\n" (binName: ''
|
||
binPath="$out/bin/${binName}"
|
||
install -D -m555 -T "${binName}" "$binPath"
|
||
rm "${binName}"
|
||
|
||
"$binPath" --bash-completion-script "$binPath" > "${binName}.bash"
|
||
installShellCompletion --bash "${binName}.bash"
|
||
rm "${binName}.bash"
|
||
"$binPath" --zsh-completion-script "$binPath" > "${binName}.zsh"
|
||
installShellCompletion --zsh "${binName}.zsh"
|
||
rm "${binName}.zsh"
|
||
"$binPath" --fish-completion-script "$binPath" > "${binName}.fish"
|
||
installShellCompletion --fish "${binName}.fish"
|
||
rm "${binName}.fish"
|
||
'') binNames}
|
||
|
||
# check that we didn’t forget any files (maybe a new binary was added)
|
||
if [ ! -z "$(${pkgs.lr}/bin/lr -1 -t 'depth == 1' .)" ]; then
|
||
echo "still some files remaining!" >&2
|
||
${pkgs.lr}/bin/lr .
|
||
exit 1
|
||
fi
|
||
|
||
'';
|
||
}
|